/**********************/
/* LOTOS-2-MML filter */
/**********************/

/* Daniel Amyot, University of Ottawa, August 10, 1996 */
/* Translates a LOTOS spec into a readable MML file.   */
/* MML files can then be imported in FrameMaker.       */
/* Compile using:  flex -i flex -i lot2html.lex */
/*                 gcc -O2 lexyy.c -o lot2html.exe */  

/* Keywords and comments (only) are enhanced with      */
/* user-defined tags (MML macros)  */ 

/* The structure of the spec and upper/lowercase characters */
/* remain unchanged.  No grammatical checking done. */

/* Last update: September 14 1996 */

/************************************************************/

%option noyywrap
%{
    #define VERSION "0.2"
    #define TODAY "September 14, 1996"
    
    #include <stdio.h>
    #include <time.h>

    struct tm *date_time;
    time_t timer;
%}

%%
[ ]         printf("<S>");
\t          printf("\t");
\n          printf("<p>\n<LC>");
\<          printf("\\<");;
\>          printf("\\>");
\\          printf("\\");

accept|actualizedby|any|behavior|behaviour|endlib|endproc|endspec|endtype|eqns|exit|for|forall|formaleqns|formalopns|formalsorts|hide|i|in|is|let|library|noexit|of|ofsort|opnnames|opns|par|process|renamedby|specification|sorts|sortnames|stop|type|using|where { 
        /* ALL KEYWORDS */
        printf("<BKW>%s<EKW>", yytext);
    };

"(*"        {
            /* COMMENTS */
            register int c;
            printf("<BCom>(*");
            for ( ; ; )
                {
                while ( (c = input()) != '*' &&
                        c != EOF )
                    switch (c) {
                        case ' '  :         printf("<S>"); break;
                        case '\t' :         printf("\t"); break;
                        case '\n' :         printf("\\n\n"); break;
                        case '<'  :         printf("\\<"); break;
                        case '>'  :         printf("\\>"); break;
                        case '\\' :         printf("\\"); break;
                        default :           printf("%c", c);
                    };    /* text comment */

                if ( c == '*' )
                    {
                    printf("*");
                    while ( (c = input()) == '*' )
                        printf("*");
                    if ( c == ')' )
                        {
                           /* End of comment */
                           printf(")<ECom>");
                           break;
                        }
                    else
                     switch (c) {
                        case ' '  :         printf("<S>"); break;
                        case '\t' :         printf("\t"); break;
                        case '\n' :         printf("\\n\n"); break;
                        case '<'  :         printf("\\<"); break;
                        case '>'  :         printf("\\>"); break;
                        case '\\' :         printf("\\"); break;
                        default :           printf("%c", c);
                    };    /* text comment */
                    }

                if ( c == EOF )
                    {
                    fprintf(stderr, "Warning: EOF in comment." );
                    printf(")<ECom>");
                    break;
                    }
                }
            }

[a-z0-9_][a-z0-9_]*  {
        /* IDENTIFIERS */;
        printf("%s", yytext);
    };

%%

/**************************************************************/

main( argc, argv )
int argc;
char **argv;
    {
    char def_file[128]="";
    char title[128]="Untitled";
    char exist_def_file=0;         /* No definition file assumed */
    
    /* SDTIN or file? */
    ++argv, --argc;  /* skip over program name */
    yyin = stdin;
    if ( argc > 0 )
        if (strnicmp(argv[0], "-h", 2))
            {
            if (!strnicmp(argv[0], "-d", 2))
                {
                    strcpy(def_file, argv[1]);
                    exist_def_file = 1;
                    if (argc > 2)
                        if ((yyin = fopen( argv[2], "r" ))==NULL)
                           {
                               fprintf(stderr, "Unknown input file. Translation aborted.\n\n");
                               exit(0);
                           }
                        else 
                           strcpy(title, argv[2]);
                }
            else
                if ((yyin = fopen( argv[0], "r" ))==NULL)
                   {
                       fprintf(stderr, "Unknown input file. Translation aborted.\n\n");
                       exit(0);
                   }
               else
                   strcpy(title, argv[0]);
               
            }
        else
        /* HELP FILE */
        {
            printf("\n\tlot2mml, (c) Daniel Amyot (damyot@csi.uottawa.ca).\n");
            printf("\tVersion %s, %s\n\n", VERSION, TODAY);

            printf("\tUsage:  lot2mml [-d DefFile] [InFile] [>OutFile]\n");
            printf("\t        lot2mml -h      (get this help file)\n\n");
            
            printf("\tWhere:  DefFile = Definition file (MML Macros). Internal default values.\n");
            printf("\t        InFile  = Input file (in LOTOS). Default is  stdin\n");
            printf("\t        OutFile = Output file (in MML). Default is  stdout\n");
            printf("\tSee also the configuration file: lot2mml.def\n\n");
            exit(0);
        }

    printf("<MML %s>\n<Comment - lot2mml, by Daniel Amyot (damyot@csi.uottawa.ca)>\n", title); 
    printf("<Comment - Version %s, %s>\n", VERSION, TODAY);
    time(&timer);
    date_time=localtime(&timer);
    printf("<Comment -\n\tTranslated on %s>\n\n", asctime(date_time));  
    /************************************************************/
    if (exist_def_file == 1)
       printf("<Comment - Macro definitions>\n<Include \"%s\">\n", def_file);
    else  /* Default definitions */
printf("<Comment *** lot2mml.def *** - Macro definitions>\n\
<Comment Daniel Amyot, September 14, 1996>\n\n\
<Comment - Do not modify this section>\n\
<!DefineMacro S \"<HardSpace>\">\n\
<!DefineMacro LC \"<LotosCode>\">\n\
<!DefineMacro p \"<S><par>\">\n\n\
<Comment - These macros can be modified but MUST BE DEFINED>\n\
<!DefineFont code\n\
    <Family Courier>\n\
    <FirstIndent 0>\n\
    <pts 9>\n\
>\n\
<!DefinePar LotosCode\n\
   <code>\n\
>\n\n\
<Comment - Make sure that Begin and End tags match!>\n\
<Comment - BeginKeyWord, EndKeyWord>\n\
<!DefineMacro BKW \"<bold>\">\n\
<!DefineMacro EKW \"<nobold>\">\n\
<Comment - BeginComment, EndComment>\n\
<!DefineMacro BCom \"<oblique>\">\n\
<!DefineMacro ECom \"<nooblique>\">\n\n\
<Comment - End of definitions>\n\n"
);
/************************************************************/

    yylex();
    }